Accumulator CPU

もっとも単純な CPU の形のひとつである。計算の途中結果を置く場所が ACC（アキュムレータ）ひとつしかなく、 すべての演算が「ACC と、メモリから読んだ値」の間で行われる。レジスタがたくさんある現代の CPU と違い、 状態が ACC と PC（次に実行する命令の番地）の2つだけなので、動きを全部追いかけられる。

命令は8ビット。上位2ビットが opcode（何をするか）、下位6ビットが address（どのデータを使うか）である。

dmem[0]=5, dmem[1]=3 を置いた状態で、次の4命令を順に実行すると dmem[2] に 8 が書き込まれる。

CPU のうち、PC の更新やメモリの読み書きといった配線はすでにできている。残っているのは 制御部（デコーダ）——「いま読んだ opcode に対して、次の ACC は何になるか、メモリに書くか、止まるか」を決める部分である。 これは組み合わせ回路なので、ここでチェックできる。

module cpu_decode (
    input      [1:0] opcode,
    input      [7:0] acc,
    input      [7:0] mem_data,
    output reg [7:0] next_acc,
    output reg       mem_we,
    output reg       halt
);

endmodule

always @(*) begin
    // まず「何もしない」を既定値にしておく
    next_acc = acc;
    mem_we   = 1'b0;
    halt     = 1'b0;

    case (opcode)
        2'b00: next_acc = mem_data;            // LOAD
        2'b01: mem_we   = 1'b1;                // STORE
        2'b10: next_acc = acc + mem_data;      // ADD
        2'b11: halt     = 1'b1;                // HALT
    endcase
end

上で書いた制御部を、PC・メモリ・クロックと組み合わせると CPU 全体になる。 クロックで状態が変わる部分（always @(posedge clk)）は、ブラウザのチェッカーでは扱えないため、 動かしてみたい人は EDA Playground を使ってください。

module cpu_accum (
    input clk, input rst,
    output [3:0] pc_out, output [7:0] acc_out, output halted
);
    reg [3:0] pc;
    reg [7:0] acc;
    reg [7:0] imem [0:15];   // 命令メモリ
    reg [7:0] dmem [0:63];   // データメモリ

    wire [7:0] instr  = imem[pc];
    wire [1:0] opcode = instr[7:6];
    wire [5:0] addr   = instr[5:0];

    // ← ここが 04 で書いた制御部（next_acc / mem_we / halt）
    wire [7:0] next_acc;
    wire mem_we, halt;
    cpu_decode dec (.opcode(opcode), .acc(acc), .mem_data(dmem[addr]),
                     .next_acc(next_acc), .mem_we(mem_we), .halt(halt));

    // クロックで状態を進める部分（順序回路）
    always @(posedge clk) begin
        if (rst) begin
            pc  <= 4'd0;
            acc <= 8'd0;
        end else if (!halt) begin
            acc <= next_acc;
            if (mem_we) dmem[addr] <= acc;
            pc <= pc + 4'd1;
        end
    end

    assign pc_out  = pc;
    assign acc_out = acc;
    assign halted  = halt;
endmodule

1. SUB 命令に変える：opcode 10 を ADD ではなく SUB（ACC − dmem[addr]）にしてみましょう。 演習Bで作った引き算がそのまま使える。チェッカーは ADD を期待しているので失敗するが、 「どのテストがどう失敗するか」を見れば、命令を1つ変えると機械の意味がどう変わるかが分かる。
2. JMP 命令を考える：PC を addr にセットする命令を足すには、制御部にどんな出力を追加すればよいでしょうか。 いまの制御部は next_acc / mem_we / halt しか出していない。
3. 命令の下位6ビットがアドレスなので、データメモリは何番地まで使えますか。これは命令フォーマットのどこで決まっていますか。
4. この CPU と、演習3のミニ CPU シミュレーター（レジスタが複数ある型）を比べて、どちらがどんな場面で有利でしょうか。